How to Install Web Interface 4.0 with ADFS Support on a Computer without Microsoft Active Directory Federation Services

Summary

This document describes how to install Web Interface 4.0 with ADFS Support on a computer that does not have Microsoft Active Directory Federation Services (ADFS) installed.

Background

The federated authentication capabilities of Web Interface 4.0 with ADFS Support can be adapted to provide support for the federated identity management software from other providers. By design, Web Interface 4.0 with ADFS Support fails to create sites if ADFS is not installed on the same computer. This article provides a sample script and procedure you can follow to use Web Interface 4.0 with ADFS Support when ADFS is not installed on the same computer.

Procedure

Perform the following steps before installing Web Interface 4.0 with ADFS Support:

Log on as an administrator.
Create a text file called adfsSchemaUpdate.vbs and copy the following sample script to that file:

‘---------------------------------------- adfsSchemaUpdate.vbs ---------------------------------

sub addStringProperty(schemaObj, propName)
    On Error Resume Next

    dim propObj
    set propObj = GetObject("IIS://localhost/Schema/" & propName)

    if (Err.Number <> 0) then
        set propObj = schemaObj.Create("Property", propName)
        propObj.Syntax = "string"
        propObj.Inherit = True
        propObj.SetInfo
    end if
end sub

sub addPropertyToClass(className, propName)
    dim classObj
    set classObj = GetObject("IIS://localhost/Schema/" & className)

    dim optPropList
    optPropList = classObj.OptionalProperties

    dim propExists
    propExists = false

    for each optEntry in optPropList
        if (optEntry = propName) then
            propExists = true
        end if
    next

    if (not propExists) then
        dim cnt
        cnt = UBound(optPropList)
        redim preserve optPropList(cnt+1)
        optPropList(cnt+1) = propName
        classObj.OptionalProperties = optPropList
        classObj.SetInfo
    end if
end sub

WScript.Echo "Starting modification of IIS Schema..."

dim schemaObj
set schemaObj = GetObject("IIS://localhost/Schema")

dim newProperties
newProperties = Array("WebSSODomain", "WebSSOPath", "WebSSORU")

for each propName in newProperties
    addStringProperty schemaObj, propName
    addPropertyToClass "IIsWebDirectory", propName
    addPropertyToClass "IIsWebVirtualDir", propName

next

WScript.Echo "Finished."

‘---------------------------------------- adfsSchemaUpdate.vbs ---------------------------------

Save the file.
Run the adfsSchemaUpdate.vbs script.
Install Web Interface 4.0 with ADFS Support.

Perform the following steps after the installation to create a Citrix Presentation Server site. If required, repeat these steps to create additional sites.

From a command line, create a Citrix Presentation Server site using the site management tool as described in CTX109702 – Web Interface with Active Directory Federation Services Support Administrator's Guide.
Open IIS Manager.
In the console tree, select your Citrix Presentation Server site.
On the Actions menu, choose Properties.
Select the Virtual Directory tab.
In the Application settings area, click Configuration.
Remove the ifsext.dll entry from the “Wildcard application maps” list and click Yes.
Click OK.

Note: If the Inheritance Overrides dialog appears, click OK without selecting any child nodes.

Click OK.

Your Citrix Presentation Server site is now ready for integration with a federated authentication solution.

More Information

Web Interface 4.0 with ADFS Support modifies the Internet Information Services (IIS) metabase when creating new sites. Some of these modifications are valid only if ADFS is installed on the computer. Without ADFS, the modifications cause an error.

The sample script in this article updates the schema of the IIS metabase so that the modifications made by the Web Interface are accepted without causing an error. These modifications do not affect the performance of IIS. One of the modifications to the wildcard application maps, however, must be removed from each site manually by following the procedure above.

For more information about Web Interface 4.0 with ADFS Support, see CTX110118 – Web Interface 4.0 with ADFS support - Frequently Asked Questions.